注：此命令流是一個很好的地震分析示例，包括模態分析、反應譜分析和時程動力分析。

! 一個四層彈簧－質點模型的地震ANSYS分析
! Example of seismic analysis in ANSYS
! 包括頻率分析，譜分析和時程分析
! With model & frequency analysis, spectrum analysis and transient analysis
! 作者：陸新征，清華大學土木工程系
! Author: Lu Xinzheng Dept. Civil Engrg. of Tsinghua University

FINI
/CLEAR
/UNITS,SI
/PREP7
DAMPRATIO=0.02 !振型阻尼系數都為0.02
ET,1,BEAM188
KEYOPT,1,7,1
KEYOPT,1,8,1
ET,2,MASS21,,,4
MP,EX,1,210E9
MP,NUXY,1,0.3
MP,DENS,1,7800
MPDATA,DAMP,1,,DAMPRATIO
SECTYPE,3,BEAM,I
SECDATA,0.2,0.2,0.5,0.01,0.01,0.008
R,1,1.6E2,1.6E2
R,2,1.2E2,1.2E2
K,1,0,0,0
K,2,0,3,0
K,3,0,6,0
K,4,0,9,0
K,5,0,12,0
K,6,0,0,10000
L,1,2
L,2,3
L,3,4
L,4,5
LSEL,,,,1,4
LATT,1,0,1,,6,,3
ALLS
LESIZE,ALL, , ,3 , , , , ,1
LMESH,ALL
NUMMRG,ALL
NUMCMP,ALL
TYPE,2
REAL,1
E,2
TYPE,2
REAL,2
E,8
E,14
E,20
*SET,NT,1001
*SET,DT,0.02
*DIM,AC,,NT
*VREAD,AC(1),RECORD,TXT
(F8.3)
/SOLU
D,1,ALL,
ANTYPE,0
SOLVE
FINISH
/SOLU !模態分析
ANTYPE,2
MODOPT,SUBSP,8
MXPAND,8, , ,1
SOLVE
FINI
!得到自振頻率1
*GET,FREQ1,MODE,1,FREQ
/ESHAPE,1.0
/SOLU
ANTYPE,SPECTR !譜分析
SPOPT,SPRS
MDAMP,1,DAMPRATIO, , , , , ,
SED,1
SVTYPE,2,1
FREQ,0.167,0.25,0.333,0.44444,0.5,0.667,1,1.25,1.667
SV,,0.154350625,0.191590625,0.210210625,0.224175625,0.250716714,0.329514922,0.484352764,0.598723486,0.786897371
FREQ,2.222,10,100000
SV,,1.034212766,1.034212766,0.3528
!按7度多遇地震，地震影響系數0.08 第一組III場地TG＝0.45
SRSS,0.01,DISP
SOLVE
FINISH
/POST1
/INP,,MCOM
NSORT,U,SUM
*GET,DMAX_SPE,SORT, ,MAX !反應譜最大變形

!開始地震計算
FINISH
/CONFIG,NRES,20000
/SOLU
ANTYPE,TRANS
TRNOPT,FULL
!設定瑞雷阻尼數值
ALPHAD,2*DAMPRATIO*FREQ1*2*3.1415926
BETAD,2*DAMPRATIO/(FREQ1*2*3.1415926)

*DO,I,1,1001
ACEL,AC(I),0,0
TIME,I*0.02
OUTRES,ALL,ALL
SOLVE
*ENDDO
FINISH

/POST26
FILE
NSOL,2,20,U,X,
PLVAR,2, , , , , , , , , ,
STORE,MERGE
XVAR,1
PLVAR,2,
*GET,DMAX_TRANS,VARI,2,EXTREM,VMAX, , ! 時程分析最大位移

命令流及地震記錄文件下載：

ansysExam_Quake.rar