本文介紹了ansys不同單元間的相關(guān)連接方法。

　　一般來說，按“桿梁殼體”單元順序，只要后一種單元的自由度完全包含前一種單元的自由度，則只要有公共節(jié)點(diǎn)即可，不需要約束方程，否則需要耦合自由度與約事方程。

　　例如：

　　(1)桿與梁、殼、體單元有公共節(jié)點(diǎn)即可，不需要約束方程。

　　(2)梁與殼有公共節(jié)點(diǎn)即可，也不需要約束寫約束方程;殼梁自由度數(shù)目相同，自由度也相同，盡管殼的rotz是虛的自由度，也不妨礙二者之間的關(guān)系，這有點(diǎn)類同于梁與桿的關(guān)系。

　　(3)梁與體則要在相同位置建立不同的節(jié)點(diǎn) ，然后在節(jié)點(diǎn)處耦合自由度與施加約束方程。

　　(4)殼與體則也要相同位置建立不同的節(jié)點(diǎn) ，然后在節(jié)點(diǎn)處耦合自由度與施加約束方程。

　　舉例：

　　有一長為100mm的矩形截面梁，截面為10X1mm，與一規(guī)格為20mmX7mmX10mm的實(shí)體連接，約束實(shí)體的端面，在梁端施加大小為3N的y方向的壓力，梁與實(shí)體都為一材料 ，彈性模量為30Gpa，泊松比為0.3。本例主要講解梁與實(shí)體連接處如何利用耦合及約束方程進(jìn)行處理。

　　命令流如下：

　　FINI

　　/CLE

　　/FILNAME,BEAM_AND_SOLID_ELEMENTS_CONNECTION !定義工作文件名

　　/TITLE,COUPLE_AND_CONSTRAINT_EQUATION !定義工作名

　　/PREP7

　　ET,1,SOLID95 !定義實(shí)體單元類型為SOLID95

　　ET,2,BEAM4 !定義梁單元類型為BEAM4

　　MP,EX,1,3E4 !定義材料的彈性模量

　　MP,PRXY,1,0.3 !定義泊松比

　　R,1 !定義實(shí)體單元實(shí)常數(shù)

　　R,2,10.0,10/12.0,1000/12.0,10.0,1.0 !定義梁單元實(shí)常數(shù)

　　BLC4,,,20,7,10 !創(chuàng)建矩形塊為實(shí)體模型

　　WPOFFS,0,3.5 !將工作平面向Y方向移動3.5

　　WPROTA,0,90 !將工作平面繞X軸旋轉(zhuǎn)90度

　　VSBW,ALL !將實(shí)體沿工作平面剖開

　　WPOFFS,0,5 !將工作平面向Y方向移動5

　　WPROTA,0,90 !將工作平面繞X軸旋轉(zhuǎn)90度

　　VSBW,ALL !將實(shí)體沿工作平面剖開

　　WPCSYS,-1 !將工作平面設(shè)為與總體笛卡兒坐標(biāo)一致

　　K,100,20,3.5,5 !創(chuàng)建關(guān)鍵點(diǎn)

　　K,101,120,3.5,5 !創(chuàng)建關(guān)鍵點(diǎn)

　　L,100,101 !連接關(guān)鍵點(diǎn)生成梁的線實(shí)體

　　LSEL,S,LOC,X,21,130 !選擇梁線

　　LATT,1,2,2 !指定梁的單元屬性

　　LESIZE,ALL,,,10 !指定梁上的單元份數(shù)

　　LMESH,ALL !劃分梁單元

　　VSEL,ALL !選擇所有實(shí)體

　　VATT,1,1,1 !設(shè)置實(shí)體的單元屬性

　　ESIZE,1 !指定實(shí)體單元尺寸

　　MSHAPE,0,2D !設(shè)置實(shí)體單元為2D

　　MSHKEY,1 !設(shè)置為映射網(wǎng)格劃分方法

　　VMESH,ALL !劃分實(shí)體單元

　　ALLS !全選

　　FINI !退出前處理

　　!------------------------

　　/SOLU !進(jìn)入求解器

　　ASEL,S,LOC,X,0 !選擇實(shí)體的端面

　　DA,ALL,ALL !約束實(shí)體端面

　　ALLS !全選

　　FK,101,FY,-3.0 !在兩端施加Y向壓力

　　CP,1,UX,1,21 !耦合節(jié)點(diǎn)1和節(jié)點(diǎn)21X方向自由度

　　CP,2,UY,1,21 !耦合節(jié)點(diǎn)1和節(jié)點(diǎn)21Y方向自由度

　　CP,3,UZ,1,21 !耦合節(jié)點(diǎn)1和節(jié)點(diǎn)21Z方向自由度

　　CE,1,0,626,UX,1,2328,UX,-1,1,ROTY,-ABS(NZ(626)-NZ(2328)) !設(shè)置約束方程

　　CE,2,0,67,UX,1,4283,UX,-1,1,ROTZ,-ABS(NY(67)-NY(4283)) !設(shè)置約束方程

　　CE,3,0,67,UZ,1,4283,UZ,-1,1,ROTX,-ABS(NY(67)-NY(4283)) !設(shè)置約束方程

　　ALLS !全選

　　SOLVE !保存

　　FINI !退出求解器

　　!------------------------

　　/POST1 !進(jìn)入通用后處理

　　PLNSOL, U,Y, 0,1.0 !顯示Y方向位移

　　PLNSOL, S,EQV, 0,1.0 !顯示等效應(yīng)力

　　ETABLE,ZL1,SMISC,1 !讀取梁單元上I節(jié)點(diǎn)X方向的力

　　ETABLE,ZL2,SMISC,7 !讀取梁單元上J節(jié)點(diǎn)X方向的力

　　ETABLE,MZ1,SMISC,6 !讀取梁單元上I節(jié)點(diǎn)Z方向的力矩

　　ETABLE,MZ2,SMISC,12 !讀取梁單元上J節(jié)點(diǎn)Z方向的力矩

　　PLETAB,ZL1 !顯示梁單元X方向的力

　　PLETAB,MZ1 !顯示梁單元Z方向力矩

　　!**********************************************

　　上面所述的不同單元之間的接連方法主要是用耦合自由度和約束方程來實(shí)現(xiàn)的，有一定的局限性，只適用于小位移，下面介紹一種支持大位移算法的方法，MPC法。

　　MPC即Multipoint Constraint,多點(diǎn)約束方程，其原理與前面所說的方程的技術(shù)幾乎一致，將不連續(xù)、自由度不協(xié)調(diào)的單元網(wǎng)格連接起來，不需要連接邊界上的節(jié)點(diǎn)完全一一對應(yīng)。

　　MPC能夠連接的模型一般有以下幾種。

　　solid 模型-solid 模型

　　shell模型-shell模型

　　solid 模型-shell 模型

　　solid 模型-beam 模型

　　shell 模型-beam模型

　　在 ANSYS中，實(shí)現(xiàn)上述MPC技術(shù)有三種途徑。

　　(1)通過MPC184單元定義模型的剛性或者二力桿連接關(guān)系。定義MPC184單元模型與定義桿的操作完全一致，而MPC單元的作用可以是剛性桿(三個自由度的連接關(guān)系)或者剛性梁(六個自由度的連接關(guān)系)。

　　(2)利用約束方程菜單路徑Main Menu>preprocessor>Coupling/Ceqn>shell/solid Interface創(chuàng)建殼與實(shí)體模型之間的裝配關(guān)系。

　　(3)利用ANSYS接觸向?qū)Чδ芏x模型之間的裝配關(guān)系。選擇菜單路徑Main Menu>preprocessor>Modeling>Creat>Contact Pair，彈出一序列的接觸向?qū)υ捒?，按照提示進(jìn)行操作，在創(chuàng)建接觸對前，單擊Optional setting按鈕彈出Contact properties對話框，將Basic選項(xiàng)卡中的Contact algorithm即接觸算法設(shè)置為MPC algorithm。或者，在定義完接觸對后，再將接觸算法修改為MPC algorithm，就相當(dāng)于定義MPC多點(diǎn)約束關(guān)系進(jìn)行多點(diǎn)約束算法。